// Detects changes to Dynamic Membership Rules for specified groups (often used in CA exclusions)
let monitoredGroups = dynamic(["Group1", "Group2"]); // <-- Customize this list
AuditLogs
| where OperationName == "Update group"
| where AdditionalDetails[0].value == "DynamicMembership"
| extend DynamicGroupName = tostring(TargetResources[0].displayName)
| where DynamicGroupName in (monitoredGroups)
| extend modifiedBy = tostring(InitiatedBy.user.userPrincipalName)
| extend accountName = tostring(split(modifiedBy, "@")[0])
| extend upnSuffix = tostring(split(modifiedBy, "@")[1])
| extend oldRule = tostring(TargetResources[0].modifiedProperties[0].oldValue)
| extend newRule = tostring(TargetResources[0].modifiedProperties[0].newValue)
| where oldRule != newRule
| project
TimeGenerated,
OperationName,
DynamicGroupName,
modifiedBy,
accountName,
upnSuffix,
result = Result,
oldRule,
newRule
| order by TimeGenerated desc
description: // Detects changes to Dynamic Membership Rules for specified groups (often used in CA exclusions)
queryPeriod: 5m
severity: High
triggerThreshold: 0
queryFrequency: 5m
tactics:
- PrivilegeEscalation
version: 1.0.1
OriginalUri: https://github.com/Azure/Azure-Sentinel/blob/master/Solutions/Microsoft Entra ID/Analytic Rules/Conditional Access - Dynamic Group Exclusion Changes.yaml
query: |-
// Detects changes to Dynamic Membership Rules for specified groups (often used in CA exclusions)
let monitoredGroups = dynamic(["Group1", "Group2"]); // <-- Customize this list
AuditLogs
| where OperationName == "Update group"
| where AdditionalDetails[0].value == "DynamicMembership"
| extend DynamicGroupName = tostring(TargetResources[0].displayName)
| where DynamicGroupName in (monitoredGroups)
| extend modifiedBy = tostring(InitiatedBy.user.userPrincipalName)
| extend accountName = tostring(split(modifiedBy, "@")[0])
| extend upnSuffix = tostring(split(modifiedBy, "@")[1])
| extend oldRule = tostring(TargetResources[0].modifiedProperties[0].oldValue)
| extend newRule = tostring(TargetResources[0].modifiedProperties[0].newValue)
| where oldRule != newRule
| project
TimeGenerated,
OperationName,
DynamicGroupName,
modifiedBy,
accountName,
upnSuffix,
result = Result,
oldRule,
newRule
| order by TimeGenerated desc
suppressionDuration: 5h
triggerOperator: gt
name: Conditional Access - Dynamic Group Exclusion Changes
requiredDataConnectors:
- connectorId: AzureActiveDirectory
dataTypes:
- AuditLogs
relevantTechniques:
- T1484
suppressionEnabled: false
eventGroupingSettings:
aggregationKind: AlertPerResult
kind: Scheduled
incidentConfiguration:
createIncident: true
groupingConfiguration:
lookbackDuration: PT5H
groupByAlertDetails: []
enabled: false
matchingMethod: AllEntities
groupByCustomDetails: []
groupByEntities: []
reopenClosedIncident: false
entityMappings:
- entityType: Account
fieldMappings:
- identifier: Name
columnName: accountName
- identifier: UPNSuffix
columnName: upnSuffix
id: c385944b-17b9-4b2b-921e-0e8d0341a675
